'##############################
'Капот и дверь радиатора - скрипт
'##############################
'
' Для ЛиАЗ-677М, ЛАЗ-695Н
' =============================
' История файла:
' Кузнецов Петр aka moskur	12.07.2012	Создание файла
' Кузнецов Петр aka moskur	02.08.2012	Модификация под ЛАЗ-695Н
' Кузнецов Петр aka moskur	04.08.2012	Модификация под улучшение охлаждения
' =============================
'

' Макрос инициализации температурного фактора


'===== Центральный капот (4 положения) ======

{trigger:kapot_1}
	(L.L.cp_kapot_1) !
	(L.L.cp_kapot_1_rot) ! &&
	(L.L.cp_kapot_1_trans) ! &&	 
	{if}
		1 (S.L.cp_kapot_1)
		(T.L.ev_klappfenster_opn)		 
	{else}
		(L.L.cp_kapot_1)
		{if}
			1 (S.L.cp_kapot_1_rot)
			0 (S.L.cp_kapot_1)
			(T.L.ev_klappfenster_opn)			
		{else}
			(L.L.cp_kapot_1_rot)
			{if}
				1 (S.L.cp_kapot_1_trans)
				0 (S.L.cp_kapot_1) (S.L.cp_kapot_1_rot)
				(T.L.ev_klappfenster_opn)				
			{else}
				0 (S.L.cp_kapot_1_trans) (S.L.cp_kapot_1) (S.L.cp_kapot_1_rot) 				
				(T.L.ev_klappfenster_cls)
			{endif}
		{endif}
	{endif}
(M.L.Kap_Faktor_1)
{end}

'===== Дверь радиатора (3 положения) ======

{trigger:kapot_2}
	(L.L.cp_kapot_2) !
	(L.L.cp_kapot_2_rot) ! &&		
	{if}
		1 (S.L.cp_kapot_2)
		(T.L.ev_klappfenster_opn)		
	{else}
		(L.L.cp_kapot_2)
		{if}
			1 (S.L.cp_kapot_2_rot)
			0 (S.L.cp_kapot_2)
			(T.L.ev_klappfenster_opn)				
			{else}
				0 (S.L.cp_kapot_2) (S.L.cp_kapot_2_rot)	
				(T.L.ev_klappfenster_cls)
			{endif}		
	{endif}
(M.L.Kap_Faktor_2)
{end}

' Макрос звука капотов (от люков)
{macro:klappfenstersound}
	l1
	{if}
		(T.L.ev_klappfenster_opn)
	{else}
		(T.L.ev_klappfenster_cls)
	{endif}	
{end}

' Макрос температурного фактора центрального капота
{macro:Kap_Faktor_1}
0 (L.L.cp_kapot_1) =
0 (L.L.cp_kapot_1_rot) = &&
0 (L.L.cp_kapot_1_trans) = &&	
{if}
1 (S.L.Kap1_Faktor)
{else}
	1 (L.L.cp_kapot_1) =
	{if}
	1.1 (S.L.Kap1_Faktor)
	{else}
		1 (L.L.cp_kapot_1_rot) =
		{if}
		1.2 (S.L.Kap1_Faktor)
		{else}
			1 (L.L.cp_kapot_1_trans) =
			{if}
			1.8 (S.L.Kap1_Faktor)
			{endif}
		{endif}
	{endif}
{endif}
(M.L.Kap_Faktor)
{end}

' Макрос температурного фактора двери радиатора
{macro:Kap_Faktor_2}
0 (L.L.cp_kapot_2) =
0 (L.L.cp_kapot_2_rot) = &&	
{if}
1 (S.L.Kap2_Faktor)
{else}
	1 (L.L.cp_kapot_2) =
	{if}
	1.15 (S.L.Kap2_Faktor)
	{else}
		1 (L.L.cp_kapot_2_rot) =
		{if}
		1.2 (S.L.Kap2_Faktor)
		{endif}
	{endif}
{endif}
(M.L.Kap_Faktor)
{end}

' Макрос общего температурного фактора
{macro:Kap_Faktor}
	(L.L.Kap1_Faktor) (L.L.Kap2_Faktor) * (S.L.Kap_Faktor)
{end}