'-------------------------------------------------------------
'Бегущая строка

	(L.L.elec_busbar_main)
	(L.L.cp_integral_sw) 1 = &&
	{if}
		(L.L.counter_1) 3 =
		{if}
			8 (S.L.upd_time)
		{else}
			6 (S.L.upd_time)
		{endif}	
		
		(L.L.counter_2) (L.L.upd_time) <
		{if}
			(L.L.counter_2) (L.S.Timegap) + (S.L.counter_2)
		{else}
			0 (S.L.counter_2)
			(L.$.Matrix_str) (S.$.Matrix_Oldstr)
			(L.L.counter_1) 3 <
			{if}
				(L.L.counter_1) 1 + (S.L.counter_1)
			{else}
				0 (S.L.counter_1)
			{endif}
		{endif}
		
		(L.L.counter_1) 0 =
		{if}
			"   МАЗ 107.065  " (S.$.Matrix_Newstr)
		{endif}
		
		(L.L.counter_1) 1 =
		{if}
			" BY ALEKSEI2506 " (S.$.Matrix_Newstr)
		{endif}
		
		(L.L.counter_1) 2 =
		{if}
			"  RVTeam.name  " (S.$.Matrix_Newstr)
		{endif}
		
		(L.L.counter_1) 3 =
		{if}
'Вывод даты и время
'	Tag: День:
				(L.S.Day) "02" $IntToStrEnh "." $+
'	Monat: Месяц :
				(L.S.Month) "02" $IntToStrEnh $+ "." $+
'	Jahr: Год :
				(L.S.Year) $IntToStr 2 $SetLengthR $+ "   " $+
'	Stunden: Часы :
				(L.S.Time) 3600 / s0 trunc s1 "02" $IntToStrEnh $+
				":" $+
'	Minuten: Минуты :
				l0 l1 - 60 * trunc "02" $IntToStrEnh $+
				(S.$.Matrix_Newstr)
			{endif}

			(L.L.counter_2) (C.L.Matrix_Waittime) - 0 max 16 * 5 / trunc 16 min s3


'Вывод строки
'((Уезжает влево))
			(L.$.Matrix_Oldstr) 16 l3 - $SetLengthR
			(L.$.Matrix_Newstr) l3 $SetLengthL $+
			(S.$.Matrix_str)
			
	{else}
		"                " (S.$.Matrix_str)	
	{endif}

	
	
'-------------------------------------------------------------
